SPI controlled display with SD card reader

Using SD card to load image on to display. Must use 2.8…3.3V external power supply or resistive level sifter. Remove SD card before connecting to USB and transferring program to Arduino.

Connect external power supply to 5V output pin. It does not harm Arduino in any way. Remove power supply connection before connecting USB or it will harm computer.

Arduino connection
  • SCLK (Serial Clock) to pin D13
  • MISO (Master Input ← Slave Output) to pin D12
  • MOSI (Master Output → Slave Input) to pin D11
  • TFT_CS (TFT display Chip Select) to pin D10
  • D/C (Data/Control) to pin D9
  • Reset to pin D8
  • SD_CS (SD card Chip Select) to pin D4

Adafruits example code for reading image from SD card and display it on screen. It is licensed with MIT license. Image must be in root directory in BMP format. SD card must be formatted to FAT16 or FAT32 format.

/***************************************************
  This is an example sketch for the Adafruit 2.2" SPI display.
  This library works with the Adafruit 2.2" TFT Breakout w/SD card
  ----> http://www.adafruit.com/products/1480
 
  Check out the links above for our tutorials and wiring diagrams
  These displays use SPI to communicate, 4 or 5 pins are required to
  interface (RST is optional)
  Adafruit invests time and resources providing this open source code,
  please support Adafruit and open-source hardware by purchasing
  products from Adafruit!

  Written by Limor Fried/Ladyada for Adafruit Industries.
  MIT license, all text above must be included in any redistribution
 ****************************************************/

#include <Adafruit_GFX.h>    // Core graphics library
#include "Adafruit_ILI9340.h" // Hardware-specific library
#include <SPI.h>
#include <SD.h>

#if defined(__SAM3X8E__)
    #undef __FlashStringHelper::F(string_literal)
    #define F(string_literal) string_literal
#endif

// TFT display and SD card will share the hardware SPI interface.
// Hardware SPI pins are specific to the Arduino board type and
// cannot be remapped to alternate pins.  For Arduino Uno,
// Duemilanove, etc., pin 11 = MOSI, pin 12 = MISO, pin 13 = SCK.
#define TFT_RST 8
#define TFT_DC 9
#define TFT_CS 10
#define SD_CS 4

Adafruit_ILI9340 tft = Adafruit_ILI9340(TFT_CS, TFT_DC, TFT_RST);

void setup(void) {
  Serial.begin(9600);

  Serial.print("Initializing SD card...");
  if (!SD.begin(SD_CS)) {
    Serial.println("failed!");
    return;
  }
  Serial.println("OK!");

  tft.begin();
  tft.fillScreen(ILI9340_BLUE);
  

  bmpDraw("myy.bmp", 0, 0);
}

void loop() {
}

// This function opens a Windows Bitmap (BMP) file and
// displays it at the given coordinates.  It's sped up
// by reading many pixels worth of data at a time
// (rather than pixel by pixel).  Increasing the buffer
// size takes more of the Arduino's precious RAM but
// makes loading a little faster.  20 pixels seems a
// good balance.

#define BUFFPIXEL 20

void bmpDraw(char *filename, uint16_t x, uint16_t y) {

  File     bmpFile;
  int      bmpWidth, bmpHeight;   // W+H in pixels
  uint8_t  bmpDepth;              // Bit depth (currently must be 24)
  uint32_t bmpImageoffset;        // Start of image data in file
  uint32_t rowSize;               // Not always = bmpWidth; may have padding
  uint8_t  sdbuffer[3*BUFFPIXEL]; // pixel buffer (R+G+B per pixel)
  uint8_t  buffidx = sizeof(sdbuffer); // Current position in sdbuffer
  boolean  goodBmp = false;       // Set to true on valid header parse
  boolean  flip    = true;        // BMP is stored bottom-to-top
  int      w, h, row, col;
  uint8_t  r, g, b;
  uint32_t pos = 0, startTime = millis();

  if((x >= tft.width()) || (y >= tft.height())) return;

  Serial.println();
  Serial.print("Loading image '");
  Serial.print(filename);
  Serial.println('\'');

  // Open requested file on SD card
  if ((bmpFile = SD.open(filename)) == NULL) {
    Serial.print("File not found");
    return;
  }

  // Parse BMP header
  if(read16(bmpFile) == 0x4D42) { // BMP signature
    Serial.print("File size: "); Serial.println(read32(bmpFile));
    (void)read32(bmpFile); // Read & ignore creator bytes
    bmpImageoffset = read32(bmpFile); // Start of image data
    Serial.print("Image Offset: "); Serial.println(bmpImageoffset, DEC);
    // Read DIB header
    Serial.print("Header size: "); Serial.println(read32(bmpFile));
    bmpWidth  = read32(bmpFile);
    bmpHeight = read32(bmpFile);
    if(read16(bmpFile) == 1) { // # planes -- must be '1'
      bmpDepth = read16(bmpFile); // bits per pixel
      Serial.print("Bit Depth: "); Serial.println(bmpDepth);
      if((bmpDepth == 24) && (read32(bmpFile) == 0)) { // 0 = uncompressed

        goodBmp = true; // Supported BMP format -- proceed!
        Serial.print("Image size: ");
        Serial.print(bmpWidth);
        Serial.print('x');
        Serial.println(bmpHeight);

        // BMP rows are padded (if needed) to 4-byte boundary
        rowSize = (bmpWidth * 3 + 3) & ~3;

        // If bmpHeight is negative, image is in top-down order.
        // This is not canon but has been observed in the wild.
        if(bmpHeight < 0) {
          bmpHeight = -bmpHeight;
          flip      = false;
        }

        // Crop area to be loaded
        w = bmpWidth;
        h = bmpHeight;
        if((x+w-1) >= tft.width())  w = tft.width()  - x;
        if((y+h-1) >= tft.height()) h = tft.height() - y;

        // Set TFT address window to clipped image bounds
        tft.setAddrWindow(x, y, x+w-1, y+h-1);

        for (row=0; row<h; row++) { // For each scanline...

          // Seek to start of scan line.  It might seem labor-
          // intensive to be doing this on every line, but this
          // method covers a lot of gritty details like cropping
          // and scanline padding.  Also, the seek only takes
          // place if the file position actually needs to change
          // (avoids a lot of cluster math in SD library).
          if(flip) // Bitmap is stored bottom-to-top order (normal BMP)
            pos = bmpImageoffset + (bmpHeight - 1 - row) * rowSize;
          else     // Bitmap is stored top-to-bottom
            pos = bmpImageoffset + row * rowSize;
          if(bmpFile.position() != pos) { // Need seek?
            bmpFile.seek(pos);
            buffidx = sizeof(sdbuffer); // Force buffer reload
          }

          for (col=0; col<w; col++) { // For each pixel...
            // Time to read more pixel data?
            if (buffidx >= sizeof(sdbuffer)) { // Indeed
              bmpFile.read(sdbuffer, sizeof(sdbuffer));
              buffidx = 0; // Set index to beginning
            }

            // Convert pixel from BMP to TFT format, push to display
            b = sdbuffer[buffidx++];
            g = sdbuffer[buffidx++];
            r = sdbuffer[buffidx++];
            tft.pushColor(tft.Color565(r,g,b));
          } // end pixel
        } // end scanline
        Serial.print("Loaded in ");
        Serial.print(millis() - startTime);
        Serial.println(" ms");
      } // end goodBmp
    }
  }

  bmpFile.close();
  if(!goodBmp) Serial.println("BMP format not recognized.");
}

// These read 16- and 32-bit types from the SD card file.
// BMP data is stored little-endian, Arduino is little-endian too.
// May need to reverse subscript order if porting elsewhere.

uint16_t read16(File & f) {
  uint16_t result;
  ((uint8_t *)&result)[0] = f.read(); // LSB
  ((uint8_t *)&result)[1] = f.read(); // MSB
  return result;
}

uint32_t read32(File & f) {
  uint32_t result;
  ((uint8_t *)&result)[0] = f.read(); // LSB
  ((uint8_t *)&result)[1] = f.read();
  ((uint8_t *)&result)[2] = f.read();
  ((uint8_t *)&result)[3] = f.read(); // MSB
  return result;
}

 

SPI controlled TFT display

Normal Arduino SPI TFT display library does not work with cheap TFT displays with integrated ILI9340C controller chip. Display model is TM022HDH26. Hopefully there is two libraries made by Adafruit that works together and brings display to live. Those are easy to install from Arduino IDE Library Manager. Needed libraries are Adafruit GFX Library and Adafruit_ILI9340. Result is below.

Arduino connection
  • SCLK (Serial Clock) to pin D13
  • MOSI (Master Output → Slave Input) to pin D11
  • CS (Chip Select) to pin D10
  • D/C (Data/Control) to pin D9
  • Reset to pin D8

Simple example code for testing.

#include "SPI.h"
#include "Adafruit_GFX.h"
#include "Adafruit_ILI9340.h"

// pin definition
const byte CS = 10;
const byte DC = 9;
const byte RS = 8;

Adafruit_ILI9340 scr = Adafruit_ILI9340(CS, DC, RS);

void setup() {
  scr.begin();
  scr.fillScreen(ILI9340_BLACK);
  scr.setTextColor(ILI9340_RED);
  scr.setTextSize(3);
  scr.println("Juvar's");
  scr.setTextSize(2);
  scr.println("Electronics Corner");
  scr.setTextColor(ILI9340_WHITE);
  scr.setTextSize(1);
  scr.println("All kinds of electronics");
  scr.println();
  scr.setTextColor(ILI9340_YELLOW);
  scr.setTextSize(2);
  scr.println("Testing display with");
  scr.println("ILI9340C controller.");
}

void loop() {
  // nothing here
}

 

Testing composite video display with arduino

With TVout library it is possible to write and draw to framebuffer which is then sent to display using composite video. Result is below.


Coding is simple. Example code is below.

#include <TVout.h>
#include <fontALL.h>

TVout TV;

void setup() {
  TV.begin(PAL,144,96);
  TV.select_font(font8x8);
  TV.draw_rect(4,19,129,11,WHITE);
  TV.print(5,20,"This works fine.");
}

void loop() {
  // nothing here
}

Electrical connection follows TVout librarys default.

 

Controlling graphic dot matrix LCD display

This was very complicated project. Finally I learned how to successfully control display with Hitachi hd61830 controller chip and Arduino.

Display works with negative -13V and normal positive +5V voltages. So first I built necessary power supply. Below is it’s circuit drawing.

There is still some ripple voltage on negative line. Some more filtering is maybe needed (capacitors). Also zener goes very hot. Negative voltage regulator would be better choise for longer use. LM337 for example.

The next thing was to figure out how to control hd61830 controller chip with Arduino. Very helpful source code was found from LCDInfo forum. After that I was able to write my own code. It is below.

/* initialization sequence and cls function taken from lcd_hd61830_lib, cdragos69@yahoo.com
   http://www.skippari.net/lcd/sekalaista/lcd_hd61830_lib.zip
   found from http://forum.lcdinfo.com/viewtopic.php?t=451
*/

// pin assignment
const byte E_PIN = 4;
const byte RW_PIN = 3;
const byte RS_PIN = 2;
const byte DB7_PIN = 12;
const byte DB6_PIN = 11;
const byte DB5_PIN = 10;
const byte DB4_PIN = 9;
const byte DB3_PIN = 8;
const byte DB2_PIN = 7;
const byte DB1_PIN = 6;
const byte DB0_PIN = 5;

void setup() {
  // Permanently tied up E pin
  digitalWrite(E_PIN, HIGH);
  delay(2000);

  com(word(0x00, 0x38)); // Display ON, master mode, cursor on/blink, text mode, internal CG-ROM
  com(word(0x01, 0x75)); // 6x8 font
  com(word(0x02, 0x27)); // 40 horizontal characters
  com(word(0x03, 0x7F)); // 1/128 duty cycle (128 lines)
  com(word(0x04, 0x07)); // 8-lines cursor
  com(word(0x08, 0x00)); // Display start address low
  com(word(0x09, 0x00)); // Display start address high
  com(word(0x0A, 0x00)); // Cursor address low
  com(word(0x0B, 0x00)); // Cursor address high

  cls();

  com(word(B00001100, B01001000)); //letter H
  com(word(B00001100, B01100101)); //letter e
  com(word(B00001100, B01101100)); //letter l
  com(word(B00001100, B01101100)); //letter l
  com(word(B00001100, B01101111)); //letter o
  com(word(B00001100, B00100000)); //space
  com(word(B00001100, B01110111)); //letter w
  com(word(B00001100, B01101111)); //letter o
  com(word(B00001100, B01110010)); //letter r
  com(word(B00001100, B01101100)); //letter l
  com(word(B00001100, B01100100)); //letter d
}

void loop() {
  // nothing here
}

void cls() {
  // clear screen
  com(word(0x0A, 0x00)); // Cursor address low
  com(word(0x0B, 0x00)); // Cursor address high
  for(int i=0;i<320;i++) com(word(0x0C,0)); // reset all text memory
  com(word(0x0A, 0x00)); // Cursor address low
  com(word(0x0B, 0x00)); // Cursor address high
}

void com(word dat) {

  digitalWrite(LED_BUILTIN, HIGH); // data flow indication on

  digitalWrite(RW_PIN, LOW);
  digitalWrite(RS_PIN, HIGH);
  digitalWrite(DB7_PIN, bitRead(dat, 15));
  digitalWrite(DB6_PIN, bitRead(dat, 14));
  digitalWrite(DB5_PIN, bitRead(dat, 13));
  digitalWrite(DB4_PIN, bitRead(dat, 12));
  digitalWrite(DB3_PIN, bitRead(dat, 11));
  digitalWrite(DB2_PIN, bitRead(dat, 10));
  digitalWrite(DB1_PIN, bitRead(dat, 9));
  digitalWrite(DB0_PIN, bitRead(dat, 8));

  digitalWrite(RW_PIN, LOW);
  digitalWrite(RS_PIN, LOW);
  digitalWrite(DB7_PIN, bitRead(dat, 7));
  digitalWrite(DB6_PIN, bitRead(dat, 6));
  digitalWrite(DB5_PIN, bitRead(dat, 5));
  digitalWrite(DB4_PIN, bitRead(dat, 4));
  digitalWrite(DB3_PIN, bitRead(dat, 3));
  digitalWrite(DB2_PIN, bitRead(dat, 2));
  digitalWrite(DB1_PIN, bitRead(dat, 1));
  digitalWrite(DB0_PIN, bitRead(dat, 0));
  
  digitalWrite(LED_BUILTIN, LOW); // data flow indication off

  //wait for busy flag to go away
  digitalWrite(E_PIN, HIGH);
  digitalWrite(RW_PIN, HIGH);
  digitalWrite(RS_PIN, HIGH);
  do {
    delay(10);
  } while (digitalRead(DB7_PIN) == HIGH);
}

Display is on text-mode with internal character ROM. The next challenge is to draw something on screen. There is some more images in the meantime. Contrast trimmer is seen on centre of image and zener is it’s left side.

Schematics for Large VU-meter

Working (small scale) circuit for Large VU-meter. Now I’m going to make first large scale prototype.

Part list

All parts except relays can be found on www.taydaelectronics.com. Relays are changeable to different ones.

Testing parallel-to-serial converter with Arduino

This is a debug program to test parallel-to-serial converter.

int dataPin = 2;
int clockPin = 3;
int count = 0;

void setup() {
  pinMode(4, OUTPUT);
  pinMode(5, OUTPUT);
  pinMode(6, OUTPUT);
  pinMode(7, OUTPUT);
  pinMode(8, OUTPUT);
  pinMode(9, OUTPUT);
  pinMode(10, OUTPUT);
  pinMode(11, OUTPUT);
  pinMode(12, OUTPUT);
  pinMode(13, OUTPUT);

  pinMode(dataPin, INPUT);
  
  Serial.begin(9600); //digital pins 1 and 0  
  Serial.println("Program start...");

  word dataa = word(B11000100,B11000000);

  digitalWrite(4, bitRead(dataa,15));
  digitalWrite(5, bitRead(dataa,14));
  digitalWrite(6, bitRead(dataa,13));
  digitalWrite(7, bitRead(dataa,12));
  digitalWrite(8, bitRead(dataa,11));
  digitalWrite(9, bitRead(dataa,10));
  digitalWrite(10, bitRead(dataa,9));
  digitalWrite(11, bitRead(dataa,8));
  digitalWrite(12, bitRead(dataa,7));
  digitalWrite(13, bitRead(dataa,6));

  // For noise suppression, enable pullup on interrupt pin
  digitalWrite(clockPin, HIGH);
  attachInterrupt(digitalPinToInterrupt(clockPin), kello, RISING);
}

void loop() {
  if (count >= 16) {
    Serial.println(""); //add linefeed
    count = 0;
  }
}

void kello() {
  Serial.print(digitalRead(dataPin));
  count = count + 1;  
}

 

Uusi blogi

Harrastan ja teen työkseni elektroniikan suunnittelua, rakentelua ja ohjelmointia ja tällä sivustolla esittelen muutamia tekemiäni projekteja. Sivusto toimii samalla muistiinpanoina itselleni. Peruselektroniikasta, dokumentoinnista ja muista perusasioista olen suorittanut osatutkinnon vuosia sitten. Sen jälkeen elektroniikka-asentajan linja lopetettiin kyseisestä koulusta, joten se jäi minultakin kesken. Itse oppiminen ja kokeileminen harrastuksen kautta on opettanut sen jälkeen paljon enemmän. Minulla on myös radioamatööritutkinto, joka on antanut perustietoa radiotekniikasta ja sähköturvallisuudesta.

Sulautetut järjestelmät ovat aina kiinnostaneet minua ja nykyään ne ovatkin itsestäänselvyys lähes kaikessa elektroniikassa. Termillä tarkoitetaan tiettyyn tarkoitukseen tehtyä laitetta, jonka sisällä on tietokone. Esimerkiksi kännykkä, pyykinpesukone ja mikroaaltouuni.

Tavallisesti kyseinen rakenne on toteutettu mikrokontrollerilla, joiden käyttö ja ohjelmointi on nykyään lasten leikkiä. Siis kirjaimellisesti. Kouluissa ohjelmoidaan eri ympäristöissä tietotekniikan, käsityön ja matematiikan tunneilla, eikä siinä ole enää mitään ihmeellistä. Yleisesti käytettyjä alustoja ovat Arduino (Atmel AVR-mikrokontrolleri) ja Raspberry Pi (ARM-prosessori ja Linux). Molempia käytetään yhtä laajasti myös ammattielektroniikassa, joten nykyajan peruskoulu antaa kyllä hyvät lähtökohdat tulevaisuuden ammattilaisille.